Paper-MojangAPI/build.gradle.kts


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

plugins {
    `java-library`
    `maven-publish`
}

java {
    withSourcesJar()
    withJavadocJar()
}

repositories {
    mavenCentral()
    maven("https://libraries.minecraft.net")
}

dependencies {
    implementation(project(":paper-api"))
    api("com.mojang:brigadier:1.0.18")

    compileOnly("it.unimi.dsi:fastutil:8.2.2")
    compileOnly("org.jetbrains:annotations:18.0.0")

    testImplementation("junit:junit:4.13.1")
    testImplementation("org.hamcrest:hamcrest-library:1.3")
    testImplementation("org.ow2.asm:asm-tree:7.3.1")
}

configurations {
    val outgoing = arrayOf(runtimeElements, apiElements, named("sourcesElements"), named("javadocElements"))
    for (config in outgoing) {
        config {
            outgoing {
                capability("${project.group}:${project.name}:${project.version}")
                capability("com.destroystokyo.paper:paper-mojangapi:${project.version}")
            }
        }
    }
}

configure<PublishingExtension> {
    publications.create<MavenPublication>("maven") {
        from(components["java"])
    }
}